(load "evaluator.txt")
(load "table.txt")

(define special-forms (make-table))
(insert! 'quote
          (lambda (exp env) (text-of-quotation exp))
          special-forms)
(insert! 'set!
          (lambda (exp env) (eval-assignment exp env))
          special-forms)
(insert! 'define
          (lambda (exp env) (eval-definition exp env))
          special-forms)
(insert! 'if
          (lambda (exp env) (eval-if exp env))
          special-forms)
(insert! 'lambda
          (lambda (exp env)
                  (make-procedure (lambda-parameters exp)
                 				 (lambda-body exp)
                 				 env))
          special-forms)
(insert! 'begin
          (lambda (exp env) (eval-sequence (begin-actions exp) env))
          special-forms)
(insert! 'cond
          (lambda (exp env) (eval (cond->if exp) env))
          special-forms)

(define (eval exp env)
  (cond ((self-evaluating? exp) exp)
        ((variable? exp) (lookup-variable-value exp env))
        ((pair? exp)
         (let ((evaluate-special-form (lookup (car exp) special-forms)))
           (if evaluate-special-form
               (evaluate-special-form exp env)
               ; Normal procedure application
               (apply (eval (operator exp) env)
                      (list-of-values (operands exp) env)))))
        (else
         (error "Unknown expression type -- EVAL" exp))))